(Windows only)

Specifies environment defaults that apply to subsequent windows that the application creates. The defaults might reside in the registry or in an initialization file. The defaults can involve colors, fonts, environment variables, etc. You must specify a default in a LOAD statement before you specify it in a USE statement.

Note: Does not apply to SpeedScript programming.

Syntax

USE environment [ NO-ERROR ]
environment

A CHARACTER expression that evaluates to the name of a current environment. If environment is non-null, it must have appeared in a prior LOAD statement. If environment is the null string (""), the default environment becomes the current environment.

NO-ERROR
The NO-ERROR option is used to prevent the statement from raising ERROR and displaying error messages.

Example

This procedure loads two files, env1.ini and env2.ini, each of which contains a font definition for font0. The program displays a character string in the ABL default window using the definition for font0 from env1.ini. It then creates a new window and displays the same character string using the definition for font0 from env2.ini. Note that the procedure creates the window after the USE statement.

r-use.p 

DEFINE VARIABLE w1      AS CHARACTER NO-UNDO VIEW-AS TEXT FONT 0 
  FORMAT "x(34)" INITIAL "This is font 0 in the first window".
DEFINE VARIABLE w2      AS CHARACTER NO-UNDO VIEW-AS TEXT FONT 0 
  FORMAT "x(35)" INITIAL "This is font 0 in the second window".
DEFINE VARIABLE new_win AS HANDLE    NO-UNDO.

LOAD "env1".
LOAD "env2".

USE "env1".
DISPLAY w1 WITH NO-LABELS WITH FRAME a.
PAUSE.

USE "env2".
CREATE WINDOW new_win.
CURRENT-WINDOW = new_win.
DISPLAY w2 in WINDOW new_win WITH NO-LABELS WITH FRAME b.
PAUSE.

DELETE WIDGET new_win.

This procedure depends on the existence of files named env1.ini and env2.ini, each of which contains a font definition for font0. If you run this procedure in your environment, you must create these files.

Notes

  • The USE statement does not change the DefaultFont or the DefaultFixedFont settings. It uses only the information in the [fonts] and [colors] sections of the new current environment's initialization file.
  • Use this statement with applications (such as the AppBuilder) that build and run other applications using a unique set of environment specifications.
  • An application must use this statement after the LOAD statement and before a new window is created to make the loaded set of environment specifications apply to the new window.
  • Subsequent PUT-KEY-VALUE and GET-KEY-VALUE statements apply to the environment made available by the USE statement.

See also

GET-KEY-VALUE statement, LOAD statement, NO-ERROR option, PUT-KEY-VALUE statement